#!/usr/bin/awk -f
# Read gemtext and output strict xhtml
# v19
# each blank line after a blank line is an empty <p></p>
# extra : convert --- to <hr />
# extra : lines starting with // are comments
#
# CHANGELOG:
# * add logo according to hyperlink protocol
#   logo in <sup></sup>
# * extra : lines starting with // are comments 
# * removed &nbsp; since it is not xml
# * changed default for linklogo : disabled
#   ''foo'' -> <code>foo</code>
# * removed ''code''
# * removed linklogos in <sup>
# * added anchors to headers
# * do everything in memory to allow top-printing toc
# * fix possible duplicate id
# * fix bug for closing <ul> if lists aren't followed by a blank line
# * fix xhtml validation if id start with number
# * fix <br /> not vaild outside <p>. 
# * simpler link extension detection
# * removed toc
#
#
# options:
# -v anchors=0
#	set to 1 to enable
#	
#	display anchor links in headers, 
#	with class "anchor" (for css)

function htmlescape(s) {
	gsub(/&/,"\\&amp;",s)
	gsub(/</,"\\&lt;",s)
	gsub(/>/,"\\&gt;",s)
	gsub(/"/,"\\&quot;",s)
	gsub(/'/,"\\&apos;",s)
	return s
}

function trim(s) {
	sub(/^[[:blank:]]+/, "", s)
	sub(/[[:blank:]]+$/, "", s)
	return s
}

# commented line with //
/^\/\/[:blank:]?/ { 
	# remove leading spaces
	comment = substr($0, length($1)+2)
	printf("<!-- %s -->\n", comment);
	next
}

# non empty line
/.+/ { blank = 0 }

# anything that is not a list
/^[^\*]/ {
	if (ul == 1) { 
		ul = 0
		print "</ul>"
	}
}

# code block
/^```/ {
	if (pre) { print "</pre>" }
	else { print "<pre>" }
	pre = (pre + 1) % 2 # toggle pre
	next
}

pre {
	print htmlescape($0)
	next
}


# empty line
/^$/ {
	if (blank) { print "<p></p>" }
	blank = 1
	next
}

/^\*/ {
	if (ul == 0) { ul = 1; print "<ul>" }
	$1 = ""
	printf("<li>%s</li>\n", htmlescape(trim($0)))
	next
}

# links
/^=>/ {
	href = htmlescape($2)
	if ( NF > 2 ) { 
		title = substr($0, length($1)+ 1 + length($2)+1)
		title = htmlescape(trim(title))
	}
	else { title = href }

	href = trim(href)
	lowerhref = tolower(href)

	if ( lowerhref ~ /\.(jpg|jpeg|png|gif|svg)$/ ) {

		printf("<p><img src=\"%s\" alt=\"%s\" loading=\"lazy\" /></p>\n",
				href, title)

	} else {
		printf("<p><a href=\"%s\">%s</a></p>\n", href, title)
	}

	next
}

# header
/^#{1,3}/ {
	lvl = match($0, "[^#]") -1 # find if h3, h2 or h1
	tocn++
	headid = sprintf("_%d_%s",
		tocn, gensub(/[^[:alnum:]]/, "", "g"))
	t = substr($0, lvl+1)
	t = htmlescape(trim(t))

	printf("<h%d id=\"%s\">%s", lvl, headid, t)
	if (anchors) {
		printf(" <a class=\"anchor\" href=\"#%s\">§</a>",
				headid)
	}
	printf("</h%d>\n", lvl)
	next
}

/^>/ { 
	$1="";
	printf("<blockquote><p>%s</p></blockquote>\n",\
			htmlescape(trim($0)))
	next
}

# horizontal rule
/^---/   { print "<hr />"; next }

# normal line
1 { printf("<p>%s</p>\n", htmlescape($0)) }

END {
	if (ul == 1) { print "</ul>" }
}